Rust 수행 준비

Rust 코드 실행을 시작하기 전에 몇 가지 초기화를 실행해야 합니다.

.section .init.entry, "ax"
.global entry
entry:
    /*
     * 메모리 관리 구성을 로드하고 적용합니다. MMU와 캐시를
     * 사용 설정할 준비가 되었습니다. .
     */
 adrp x30, idmap
    msr ttbr0_el1, x30

    mov_i x30, .Lmairval
    msr mair_el1, x30

    mov_i x30, .Ltcrval
    /* 지원되는 PA 범위를 TCR_EL1.IPS에 복사합니다. */
    mrs x29, id_aa64mmfr0_el1
    bfi x30, x29, #32, #4

    msr tcr_el1, x30

    mov_i x30, .Lsctlrval

    /*
     * 이 지점 앞에 오는 모든 내용이 완료되었는지 확인하고
     * 오래된 로컬 TLB 항목을 사용하기 전에 무효화합니다.
     */
    isb
    tlbi vmalle1
    ic iallu
    dsb nsh
    isb

    /*
     * MMU와 캐시를 사용하도록 sctlr_el1을 구성하고 이 작업이
     * 완료될 때까지 진행하지 않습니다.
     */
    msr sctlr_el1, x30
    isb

    /* EL1에서 트래핑 부동 소수점 액세스를 사용 중지합니다. */
    mrs x30, cpacr_el1
    orr x30, x30, #(0x3 << 20)
    msr cpacr_el1, x30
    isb

    /* bss 섹션을 0으로 만듭니다. */
    adr_l x29, bss_begin
    adr_l x30, bss_end
0:  cmp x29, x30
    b.hs 1f
    stp xzr, xzr, [x29], #16
    b 0b

1:  /* 스택을 준비합니다. */
    adr_l x30, boot_stack_end
    mov sp, x30

    /* 예외 벡터를 설정합니다. */
    adr x30, vector_table_el1
    msr vbar_el1, x30

    /* Rust 코드를 호출합니다. */
    bl main

    /* 루프가 인터럽트를 영원히 기다립니다. */
2:  wfi
    b 2b