Підготовка до Rust

Перш ніж ми зможемо запускати код Rust, нам потрібно виконати деяку ініціалізацію.

.section .init.entry, "ax"
.global entry
entry:
    /*
     * Завантаження та застосування конфігурації керування пам'яттю, готової
     * до ввімкнення MMU та кешів.
     */
    adrp x30, idmap
    msr ttbr0_el1, x30

    mov_i x30, .Lmairval
    msr mair_el1, x30

    mov_i x30, .Ltcrval
    /* Скопіювати підтримуваний діапазон PA у TCR_EL1.IPS. */
    mrs x29, id_aa64mmfr0_el1
    bfi x30, x29, #32, #4

    msr tcr_el1, x30

    mov_i x30, .Lsctlrval

    /*
     * Перевірити все до завершення цього пункту, а потім зробити недійсними всі
     * потенційно застарілі локальні записи TLB до того, як вони почнуть використовуватися.
     */
    isb
    tlbi vmalle1
    ic iallu
    dsb nsh
    isb

    /*
     * Налаштувати sctlr_el1 на ввімкнення MMU та кешу і не продовжувати,  доки це
     * не буде зроблено.
     */
    msr sctlr_el1, x30
    isb

    /* Вимкнути перехоплення доступу з плаваючою комою в EL1. */
    mrs x30, cpacr_el1
    orr x30, x30, #(0x3 << 20)
    msr cpacr_el1, x30
    isb

    /* Обнуліть секцію bss. */
    adr_l x29, bss_begin
    adr_l x30, bss_end
0:  cmp x29, x30
    b.hs 1f
    stp xzr, xzr, [x29], #16
    b 0b

1:  /* Підготувати стек. */
    adr_l x30, boot_stack_end
    mov sp, x30

    /* Налаштування вектора виключень. */
    adr x30, vector_table_el1
    msr vbar_el1, x30

    /* Виклик коду Rust. */
    bl main

    /* Постійно циклічно чекаємо на переривання. */
2:  wfi
    b 2b